//////////////////////////////////////////////////////////////////////////////
// Section common to all game types
//////////////////////////////////////////////////////////////////////////////
include common.txt
include ffire.txt

//////////////////////////////////////////////////////////////////////////////
// Killer specific section
//////////////////////////////////////////////////////////////////////////////

variable killEnemySargeBonus 250

// in killer the black flag is an additional strategic item
if startup1 then
	deploy bkflagbase,
	deploy blackflag1,
	setitemflag blackflag1 strategic 1,
	setitemflag blackflag1 stratsquare 1

// @1 = color killed, @2 = Capitalized color (e.g. "Green"), @3 = color of killer
macro killed_sarge 3
{
	if killed @1sarge1 by @3 testvar isAlly @3 @1 = 0 and hasitem @3sarge1 blackflag1 = 1 then
		showmessage "@2 sarge killed by killer @3",
		trigger @3KilledEnemySarge
}

// @1 = color, @2 = Capitalized color (e.g. "Green"), @3-5 are other colors
macro killer_macro 5
{
	// in killer the enemy sarges should be shown on the stratmap
	if startup1 testvar iscoloringame @1 > 0 then
		setitemflag @1sarge1 strategic 1

	// check for the @1 sarge being killed and who killed them
	expand killed_sarge ( @1 "@2" @3 )
	expand killed_sarge ( @1 "@2" @4 )
	expand killed_sarge ( @1 "@2" @5 )

	// killer scoring events

	if @1KilledEnemySarge then
		addvar @1score killEnemySargeBonus,
		playsound "mp_death.wav" (0,0) 1 2,
		trigger check@1wins

	// check the flag being picked up so we can show a message and make a sound

	if pickedup blackflag1 by @1sarge1 then
		showmessage "@2 is the killer",
		playsound "mp_gotflag.wav" (0,0) 3 1,
		addscoresymbol @1 flag

	if dropped blackflag1 by @1sarge1 then
		removescoresymbol @1 flag
}

expand killer_macro ( green "Green" tan   blue  grey  )
expand killer_macro ( tan   "Tan"   green blue  grey  )
expand killer_macro ( blue  "Blue"  green tan   grey  )
expand killer_macro ( grey  "Grey"  green tan   blue  )

// if flag is dropped and not picked up for 2 minutes then return it to it's base

variable flagTimeOutVar 0
variable flagLastTimeOutVar 1

if dropped blackflag1 then
	triggerdelay 120000 flagCheckTimeOut

if pickedup blackflag1 then
    addvar flagTimeOutVar 1

if flagCheckTimeOut testvar flagTimeOutVar = flagLastTimeOutVar then
	showmessage "Black Flag was dropped and not picked up for 2 minutes - moved to base",
	createexplosion blackflag1 128 0 green,
	playsound "mp_rebaseflag.wav" 0 1,
    moveitem blackflag1 bkflagbase,
	triggerdelay 1000 flagLastTimeOutIncr

if flagCheckTimeOut testvar flagTimeOutVar <> flagLastTimeOutVar then
	triggerdelay 1000 flagLastTimeOutIncr

if flagLastTimeOutIncr then
	addvar flagLastTimeOutVar 1